festival.edmaven.com:80

Linux b747.shapiroconsult.com 3.10.0-1160.119.1.vz7.224.4 #1 SMP Mon Sep 30 15:36:27 MSK 2024 x86_64
Apache
173.231.212.80

group.awk

# group.awk --- functions for dealing with the group file
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993
# Revised October 2000
# Revised December 2010

BEGIN    \
{
    # Change to suit your system
    _gr_awklib = "/usr/libexec/awk/"
}

function _gr_init(    oldfs, oldrs, olddol0, grcat,
                             using_fw, using_fpat, n, a, i)
{
    if (_gr_inited)
        return

oldfs = FS
    oldrs = RS
    olddol0 = $0
    using_fw = (PROCINFO["FS"] == "FIELDWIDTHS")
    using_fpat = (PROCINFO["FS"] == "FPAT")
    FS = ":"
    RS = "\n"

grcat = _gr_awklib "grcat"
    while ((grcat | getline) > 0) {
        if ($1 in _gr_byname)
            _gr_byname[$1] = _gr_byname[$1] "," $4
        else
            _gr_byname[$1] = $0
        if ($3 in _gr_bygid)
            _gr_bygid[$3] = _gr_bygid[$3] "," $4
        else
            _gr_bygid[$3] = $0

n = split($4, a, "[ \t]*,[ \t]*")
        for (i = 1; i <= n; i++)
            if (a[i] in _gr_groupsbyuser)
                _gr_groupsbyuser[a[i]] = \
                    _gr_groupsbyuser[a[i]] " " $1
            else
                _gr_groupsbyuser[a[i]] = $1

_gr_bycount[++_gr_count] = $0
    }
    close(grcat)
    _gr_count = 0
    _gr_inited++
    FS = oldfs
    if (using_fw)
        FIELDWIDTHS = FIELDWIDTHS
    else if (using_fpat)
        FPAT = FPAT
    RS = oldrs
    $0 = olddol0
}
function getgrnam(group)
{
    _gr_init()
    return _gr_byname[group]
}
function getgrgid(gid)
{
    _gr_init()
    return _gr_bygid[gid]
}
function getgruser(user)
{
    _gr_init()
    return _gr_groupsbyuser[user]
}
function getgrent()
{
    _gr_init()
    if (++_gr_count in _gr_bycount)
        return _gr_bycount[_gr_count]
    return ""
}
function endgrent()
{
    _gr_count = 0
}

Name	Type	Size	Owner/Group	Permission	Last Modified	Actions
.	dir	-	root/root	0755	2024-07-03 03:51:26
..	dir	-	root/root	0755	2024-06-17 09:22:38
assert.awk	text/plain	382 B	root/root	0644	2024-03-28 07:26:26
bits2str.awk	text/plain	327 B	root/root	0644	2024-03-28 07:26:26
cliff_rand.awk	text/plain	307 B	root/root	0644	2024-03-28 07:26:26
ctime.awk	text/plain	233 B	root/root	0644	2024-03-28 07:26:27
ftrans.awk	text/plain	317 B	root/root	0644	2024-03-28 07:26:27
getopt.awk	text/plain	2.18 KB	root/root	0644	2024-03-28 07:26:27
gettime.awk	text/plain	2.43 KB	root/root	0644	2024-03-28 07:26:27
group.awk	text/plain	1.75 KB	root/root	0644	2024-03-28 07:26:26
join.awk	text/plain	378 B	root/root	0644	2024-03-28 07:26:27
libintl.awk	text/x-c	238 B	root/root	0644	2024-03-28 07:26:27
noassign.awk	text/plain	425 B	root/root	0644	2024-03-28 07:26:27
ord.awk	text/plain	937 B	root/root	0644	2024-03-28 07:26:27
passwd.awk	text/plain	1.17 KB	root/root	0644	2024-03-28 07:26:26
quicksort.awk	text/plain	1023 B	root/root	0644	2024-03-28 07:26:27
readable.awk	text/plain	492 B	root/root	0644	2024-03-28 07:26:27
rewind.awk	text/plain	404 B	root/root	0644	2024-03-28 07:26:27
round.awk	text/plain	661 B	root/root	0644	2024-03-28 07:26:27
strtonum.awk	text/plain	1.43 KB	root/root	0644	2024-03-28 07:26:27
walkarray.awk	text/plain	214 B	root/root	0644	2024-03-28 07:26:27
zerofile.awk	text/plain	424 B	root/root	0644	2024-03-28 07:26:27